17.1.1. The Screenshot.

17.1.2. The Code.

The program can be found here: 'gtk2_toolbar.pl'

 #! /usr/bin/perl -w
 
 use strict;
 use Gtk2 '-init';
 use Glib qw/TRUE FALSE/; 
 
 my $tt = Gtk2::Tooltips->new();
 
 #standard window creation, placement, and signal connecting
 my $window = Gtk2::Window->new('toplevel');
 $window->signal_connect('delete_event' => sub { Gtk2->main_quit; });
 $window->set_border_width(5);
 $window->set_position('center_always');
 
 #this vbox will return the bulk of the gui
 my $vbox = &ret_vbox();
 
 #add and show the vbox
 $window->add($vbox);
 $window->show();
 
 #our main event-loop
 Gtk2->main();
 
 sub ret_vbox {
 
 my $vbox = Gtk2::VBox->new(FALSE,5);
 
 	#====================================
 	#The handle box helps in creating a detachable toolbar 
 	my $hb = Gtk2::HandleBox->new;
 	#create a toolbar, and do some initial settings
 	my $toolbar = Gtk2::Toolbar->new;
 	$toolbar->set_icon_size ('large-toolbar');
 	$toolbar->set_show_arrow (FALSE);
 	
 	#________
 	#Create a menu tool button that contains a simple menu.
 		my $t_mbtn_edit = Gtk2::MenuToolButton->new_from_stock('gtk-edit');
 		$t_mbtn_edit->set_menu (&ret_menu);
 					
 	$toolbar->insert($t_mbtn_edit,-1);
 	
 	#________
 	#Insert a separator tool item	
 	$toolbar->insert(Gtk2::SeparatorToolItem->new ,-1 );
 	
 	#________
 	#Create three radio tool buttons, radio btn "both"	
 		my $t_rbtn_both = Gtk2::RadioToolButton->new (undef);
 		$t_rbtn_both->set_label ('Both');
 		$t_rbtn_both->set_active(TRUE);
 		$t_rbtn_both->set_icon_widget (Gtk2::Image->new_from_file('./pix/tux.png'));
 		$t_rbtn_both->signal_connect('toggled', \&radio_toggled,$toolbar);
 		
 	$toolbar->insert($t_rbtn_both,-1); 
 	
 	#________
 	#radio btn "text"	
 		my $t_rbtn_text = Gtk2::RadioToolButton->new_from_widget($t_rbtn_both);
 		$t_rbtn_text->set_label ('Text');
 		$t_rbtn_text->set_icon_widget (Gtk2::Image->new_from_file('./pix/tux.png'));
 		$t_rbtn_text->signal_connect('toggled', \&radio_toggled,$toolbar);
 						
 	$toolbar->insert($t_rbtn_text,-1);
 	
 	#________
 	#radio btn "icon"
 		my $t_rbtn_icon = Gtk2::RadioToolButton->new_from_widget($t_rbtn_both);
 		$t_rbtn_icon->set_label ('Icons');
 		$t_rbtn_icon->set_icon_widget (Gtk2::Image->new_from_file('./pix/tux.png'));
 		$t_rbtn_icon->signal_connect('toggled', \&radio_toggled,$toolbar);
 		
 	$toolbar->insert($t_rbtn_icon,-1);
 	
 	#________
 	#Insert a separator tool item	
 	$toolbar->insert(Gtk2::SeparatorToolItem->new ,-1 );
 	
 	#________
 	#Insert a toggle tool button to toggle the "set_show_arrow" property
 		my $t_tbtn_arrow = Gtk2::ToggleToolButton->new_from_stock('gtk-go-down');
 		$t_tbtn_arrow->set_label ('Show Arrow');
 		$t_tbtn_arrow->signal_connect('toggled' => sub {
 		
 			($t_tbtn_arrow->get_active)&&($toolbar->set_show_arrow (TRUE));
 			($t_tbtn_arrow->get_active)||($toolbar->set_show_arrow (FALSE));		
 		});
 				
 	$toolbar->insert($t_tbtn_arrow,-1);
 	
 	#________
 	#Insert a separator tool item
 	$toolbar->insert(Gtk2::SeparatorToolItem->new ,-1 );
 	
 	#________
 	#Insert a toggle tool button to toggle the "set_tooltips" property
 		my $t_tbtn_tt = Gtk2::ToggleToolButton->new_from_stock('gtk-add');
 		$t_tbtn_tt->set_label ('Show Tooltips');
 		$t_tbtn_tt->set_active(TRUE);
 		$t_tbtn_tt->set_tooltip ($tt, "Toggle Tooltips on / off", "");
 		$t_tbtn_tt->signal_connect('toggled' => sub {
 		
 			($t_tbtn_tt->get_active)&&($toolbar->set_tooltips (TRUE));
 			($t_tbtn_tt->get_active)||($toolbar->set_tooltips (FALSE));		
 		});
 				
 	$toolbar->insert($t_tbtn_tt,-1);
 	
 	#________
 	#Insert a separator tool item
 	$toolbar->insert(Gtk2::SeparatorToolItem->new ,-1 );
 	#________
 	#Insert a separator tool item that will be used as an empty space
 		my $space = Gtk2::SeparatorToolItem->new;
 		$space->set_draw(FALSE);
 		$space->set_expand(TRUE);
 		
 	$toolbar->insert($space,-1 );
 	
 	#________
 	#Insert a tool item containing an entry widget
 		my $tool_item = Gtk2::ToolItem->new;
 			my $ent = Gtk2::Entry->new;
 		$tool_item->add($ent);
 	
 	$toolbar->insert($tool_item,-1);
 	
 	#________
 	#Insert a standard tool button 	
 		my $t_btn_find = Gtk2::ToolButton->new_from_stock ('gtk-find');
 		$t_btn_find->set_tooltip ($tt, "Find yourself", "");
 		
 	$toolbar->insert($t_btn_find,-1);
 	$hb->add($toolbar);
 	#====================================
 	
 $vbox->pack_start($hb,FALSE,FALSE,0);
 
 	$vbox->show_all();
 	
 return $vbox;
 }
 
 sub radio_toggled {
 
 	#this sub discovers which radio button is active and 
 	#sets the toolbar's style accordingly
 	my($widget,$toolbar) = @_;
 	if ($widget->get_active){
 	
 		my $lbl = $widget->get_label;
 		
 		($lbl =~ m/Text/i)&&($toolbar->set_style('text'));
 		($lbl =~ m/Icon/i)&&($toolbar->set_style('icons'));
 		($lbl =~ m/Both/i)&&($toolbar->set_style('both'));
 	
 	}
 }
 
 sub ret_menu {
 
 my $menu_edit = Gtk2::Menu->new();
 	
 $menu_edit->append(Gtk2::MenuItem->new('_Cut'));
 $menu_edit->append(Gtk2::MenuItem->new('C_opy'));
 $menu_edit->append(Gtk2::MenuItem->new('_Paste'));
 	
 $menu_edit->show_all();	
 return $menu_edit;
 	
 }

17.1.3. Points of interest.

• When you consult the man page of Gtk2::Toolbar, you will notice quite an amount of methods available to append items to it. These are deprecated methods, and should be avoided. The 'insert' method should now be used.

  $toolbar->insert ($item, $pos) 
  	* $item (Gtk2::ToolItem)
   	* $pos (integer)

  If $pos is 0 the item is prepended to the start of the toolbar. If $pos is negative, the item is appended to the end of the toolbar.

• Gtk2::ToolItem's has its own way to set Gtk2::ToolTips. The standard way to set a tooltip on a widget is:

  $tooltips->set_tip ($widget, $tip_text, $tip_private=undef) 
  	* $widget (Gtk2::Widget)
  	* $tip_text (string)
  	* $tip_private (scalar)

  Gtk2::ToolItem's method is as follows:

  $tool_item->set_tooltip ($tooltips, $tip_text, $tip_private) 
  	* $tooltips (Gtk2::Tooltips)
  	* $tip_text (string)
  	* $tip_private (string)

• A detachable Gtk2::Toolbar is created by adding it to a Gtk2::HandleBox. A Gtk2::HandleBox is just another container that can be used to pack widgets in to. The difference between it and typical containers is that it can be detached from a parent window (or, in fact, the Gtk2::HandleBox remains in the parent, but it is reduced to a very small rectangle, while all of its contents are reparented to a new freely floating window). It is usually nice to have a detachable toolbar, so these two widgets occur together quite often.

• To add a space, we use the Gtk2::SeparatorToolItem widget, and use its 'set_draw' method and set the 'draw' property to FALSE. This will make it invisible. We also sets its 'expand' property to TRUE. This will cause it to take up free space.

• The Gtk2::Toolbar features a style setting which change the appearance of the buttons in the Gtk2::Toolbar. Our demo toggles it via the Gtk2::RadioToolButtons, and gives you a choice between 'icons','text' or 'both'.

• Setting the 'show_arrow' property of Gtk2::Toolbar to TRUE, will cause the Gtk2::Toolbar widget to shrink when there is not enough space available for it.

  To see it in action, detach the toolbox and toggle the "Show Arrow" button.

• The 'set_tooltips' method of Gtk2::Toolbar will cause the Gtk2::Toolbar widget to hide or show tooltips belonging to the Gtk2::ToolItem widgets packed into it.

• The Gtk+ documentation suggest that you should only pack widgets of type Gtk2::ToolItem into a Gtk2::Toolbar. To add a widget not available as a Gtk2::ToolItem subclass, create a Gtk2::ToolItem and the widget you which to add to the Gtk2::Toolbar. Now add the your widget to the Gtk2::ToolItem instance, and insert the Gtk2::ToolItem into the Gtk2::Toolbar.

When you need to create and manage large menu structures, make use of Gtk2::UIManager ( Chapter 18 ). This replaces the deprecated Gtk2::ItemFactory.