12.2.1. Available Methods for Gtk2::TextView

There is only one function for creating a new Gtk2::TextView widget.

widget = Gtk2::TextView->new 

When a Gtk2::TextView is created it will create an associated Gtk2::TextBuffer and Gtk2::TextTagTable by default. If you want to use an existing Gtk2::TextBuffer in a Gtk2::TextView specify it in the above method. To change the Gtk2::TextBuffer used by a Gtk2::TextView use the following method:

 $text_view->set_buffer ($buffer) 
 	* $buffer (Gtk2::TextBuffer)

 textbuffer = $text_view->get_buffer 

A Gtk2::TextView can be used to allow the user to edit a body of text, or to display multiple lines of read-only text to the user. To switch between these modes of operation, the use the following method:

$text_view->set_editable ($setting) 
	* $setting (boolean)

You can retrieve the current editable setting using the method:

boolean = $text_view->get_editable 

$text_view->set_cursor_visible ($setting) 
	* $setting (boolean)

$text_view->set_wrap_mode ($wrap_mode) 
	* $wrap_mode (Gtk2::WrapMode)

none
char
word

justification = $text_view->get_justification 
$text_view->set_justification ($justification) 
	* $justification (Gtk2::Justification)

left
right
center

The justification will be "left" if the wrap_mode is "none". Tags in the associated Gtk2::TextBuffer may override the default justification.

#left margin
integer = $text_view->get_left_margin 
$text_view->set_left_margin ($left_margin) 
	* $left_margin (integer)
#right margin
integer = $text_view->get_right_margin 
$text_view->set_right_margin ($right_margin) 
	* $right_margin (integer)
#tabs
tabarray = $text_view->get_tabs 
$text_view->set_tabs ($tabs) 
	* $tabs (Gtk2::Pango::TabArray)
#indentation
integer = $text_view->get_indent 
$text_view->set_indent ($indent) 
	* $indent (integer)
#other
integer = $text_view->get_pixels_above_lines 
$text_view->set_pixels_above_lines ($pixels_above_lines) 
	* $pixels_above_lines (integer)

integer = $text_view->get_pixels_below_lines 
$text_view->set_pixels_below_lines ($pixels_below_lines) 
	* $pixels_below_lines (integer)

integer = $text_view->get_pixels_inside_wrap 
$text_view->set_pixels_inside_wrap ($pixels_inside_wrap) 
	* $pixels_inside_wrap (integer)

12.2.2. Screenshot of the Gtk2::TextView demo program

12.2.3. Classes in use

12.2.4. The Code

The program can be found here: 'TextView Demo'

 #! /usr/bin/perl -w
 
 use strict;
 use Gtk2 '-init';
 use Glib qw/TRUE FALSE/; 
  
 #standard window creation, placement, and signal connecting
 my $window = Gtk2::Window->new('toplevel');
 $window->signal_connect('delete_event' => sub { Gtk2->main_quit; });
 $window->set_border_width(5);
 $window->set_position('center_always');
 
 #this vbox will geturn the bulk of the gui
 my $vbox = &ret_vbox();
 
 #add and show the vbox
 $window->add($vbox);
 $window->show();
 
 #our main event-loop
 Gtk2->main();
 
 
 sub ret_vbox {
 
 my $vbox = Gtk2::VBox->new(FALSE,5);
 
 	my $frame = Gtk2::Frame->new("Basic Gtk2::TextView");
 		
 	#method of Gtk2::Container
 	$frame->set_border_width(5);
 	
 		my $sw = Gtk2::ScrolledWindow->new (undef, undef);
     		$sw->set_shadow_type ('etched-out');
 		$sw->set_policy ('automatic', 'automatic');
 		#This is a method of the Gtk2::Widget class,it will force a minimum 
 		#size on the widget. Handy to give intitial size to a 
 		#Gtk2::ScrolledWindow class object
 		$sw->set_size_request (300, 300);
 		#method of Gtk2::Container
 		$sw->set_border_width(5);
 		
 			my $tview = Gtk2::TextView->new();
 				my $content = `cat ./lyrics.txt`;
   			my $buffer = $tview->get_buffer();
 			$buffer->set_text($content);
 			
 		$sw->add($tview);
 	$frame->add($sw);
 $vbox->pack_start($frame,TRUE,TRUE,4);
 	
 	my $table = Gtk2::Table->new(4,5,FALSE);
 		#editable toggle
 		my $btn_editable = Gtk2::CheckButton->new("_Editable");
 			$btn_editable->set_active(TRUE);
 		$btn_editable->signal_connect('toggled' =>sub {
 			if($btn_editable->get_active){
 				$tview->set_editable(TRUE);
 			}else{
 				$tview->set_editable(FALSE);
 			}
 		});
 		
 	$table->attach_defaults($btn_editable,0,1,0,1);
 		#visible cursor toggle
 		my $btn_cursor = Gtk2::CheckButton->new("_Cursor Visible");
 			$btn_cursor->set_active(TRUE);
 		$btn_cursor->signal_connect('toggled' =>sub {
 			if($btn_cursor->get_active){
 				$tview->set_cursor_visible(TRUE);
 			}else{
 				$tview->set_cursor_visible(FALSE);
 			}
 		});
 	$table->attach_defaults($btn_cursor,0,1,1,2);
 		#left margin toggle
 		my $btn_mar_l = Gtk2::CheckButton->new("_Left Margin");
 		$btn_mar_l->signal_connect('toggled' =>sub {
 			if($btn_mar_l->get_active){
 				$tview->set_left_margin (50);
 			}else{
 				$tview->set_left_margin (0);
 			}
 		});
 	$table->attach_defaults($btn_mar_l,0,1,2,3);
 		#right margin toggle
 		my $btn_mar_r = Gtk2::CheckButton->new("_Right Margin");
 		$btn_mar_r->signal_connect('toggled' =>sub {
 			if($btn_mar_r->get_active){
 				$tview->set_right_margin (50);
 			}else{
 				$tview->set_right_margin (0);
 			}
 		});
 	
 	$table->attach_defaults($btn_mar_r,0,1,3,4);
 		#wrap mode
 		my $lbl_wrap = Gtk2::Label->new("Wrap Mode:");
 	$table->attach_defaults($lbl_wrap,1,2,0,1);	
 		
 		my $combo_wrap = Gtk2::ComboBox->new_text();
 		
 			$combo_wrap->append_text("none");
 			$combo_wrap->append_text("word");
 			$combo_wrap->append_text("char");
 			$combo_wrap->set_active(0);
 			
 		$combo_wrap->signal_connect('changed' =>sub{
 		
 			$tview->set_wrap_mode ($combo_wrap->get_active_text);
 		});
 			
 	$table->attach_defaults($combo_wrap,2,3,0,1);
 		#justification mode
 		my $lbl_just = Gtk2::Label->new("Justification:");
 	$table->attach_defaults($lbl_just,1,2,1,2);	
 	
 		my $combo_just = Gtk2::ComboBox->new_text();
 		
 			$combo_just->append_text("left");
 			$combo_just->append_text("right");
 			$combo_just->append_text("center");
 			$combo_just->set_active(0);
 			
 		$combo_just->signal_connect('changed' =>sub{
 		
 			$tview->set_justification ($combo_just->get_active_text);
 		});
 			
 	$table->attach_defaults($combo_just,2,3,1,2);
 	
 $vbox->pack_start($table,FALSE,FALSE,0);
 $vbox->show_all();
 return $vbox;
 }