14.4. Making use of Gtk2::TreeSelection.

14.4.2.1. The Screenshot

14.4.2.2. The Code

The program can be found here: 'Finding a selection'

 #! /usr/bin/perl -w
 
 use strict;
 use Gtk2 '-init';
 use Glib qw/TRUE FALSE/; 
  
 #standard window creation, placement, and signal connecting
 my $window = Gtk2::Window->new('toplevel');
 $window->signal_connect('delete_event' => sub { Gtk2->main_quit; });
 $window->set_border_width(5);
 $window->set_position('center_always');
 
 #this vbox will geturn the bulk of the gui
 my $vbox = &ret_vbox();
 
 #add and show the vbox
 $window->add($vbox);
 $window->show();
 
 #our main event-loop
 Gtk2->main();
 
 
 sub ret_vbox {
 
 my $vbox = Gtk2::VBox->new(FALSE,5);
 
 $vbox->pack_start(Gtk2::Label->new("Selection Mode:"),FALSE,FALSE,5);
 
 	#------------------
 	#get a list of Gtk2::SelectionModes and fill a combo box with it
 	my $cmb_box = Gtk2::ComboBox->new_text;
 	 
 	foreach my $s_type (Glib::Type->list_values ('Gtk2::SelectionMode')){
 	
 		$cmb_box->append_text($s_type->{'nick'});
 	}
 	
 	$cmb_box->set_active(0);
 	#------------------
 	
 $vbox->pack_start($cmb_box,FALSE,FALSE,0);
 
 $vbox->pack_start(Gtk2::HSeparator->new(),FALSE,FALSE,0);
 		
 	#this is one of the provided base Gtk2::TreeModel classes.
 	my $tree_store = Gtk2::TreeStore->new(qw/Glib::String/);
 
 	#fill it with arbitry data
 	foreach (1..3) {
 	
 		my $parent_nr = $_;
 		#the iter is a pointer in the treestore. We
 		#use to add data.
                 my $iter = $tree_store->append(undef);
 		$tree_store->set ($iter,0 => "Parent $parent_nr");
 		
                  foreach (1..3){
 		 	#here we append child iters to the parent iter
 			#and add data to those chils iters.
                       my $iter_child = $tree_store->append($iter);
 		      $tree_store->set ($iter_child,0 => "Child $_ of Parent $parent_nr");
 		}
 	}
 	
 	#this will create a treeview, specify $tree_store as its model
 	my $tree_view = Gtk2::TreeView->new($tree_store);
 	
 		#create a Gtk2::TreeViewColumn to add to $tree_view
 		my $tree_column = Gtk2::TreeViewColumn->new();
 		$tree_column->set_title ("Select Something");
 			
 			my $renderer = Gtk2::CellRendererText->new;
 			
 		$tree_column->pack_start ($renderer, FALSE);
 		$tree_column->add_attribute($renderer, text => 0);
 	
 	#add $tree_column to the treeview
 	$tree_view->append_column ($tree_column);
 	
 	$vbox->set_size_request (300, 300);
 	
 	
 	#---------------------------------------------------
 	#get the Gtk2::TreeSelection of $tree_view
 	my $treeselection = $tree_view->get_selection;
 	#set its initial mode
 	$treeselection->set_mode($cmb_box->get_active_text);
 	
 	#connect the combo box's changed signal so that it will
 	#change the mode of the Gtk2::TreeSelection on each change.
 	$cmb_box->signal_connect('changed' => sub {
 	
 		$treeselection->set_mode($cmb_box->get_active_text);
 	});
 	#-----------------------------------------------------
 	
 $vbox->pack_start($tree_view,TRUE,TRUE,0);
 $vbox->pack_start(Gtk2::HSeparator->new(),FALSE,FALSE,0);
 
 	my $btn_show_sel = Gtk2::Button->new("_Show Selected");
 	$btn_show_sel->signal_connect("clicked" => sub {
 	
 		my $treeselection = $tree_view->get_selection;
 		
 		$treeselection->selected_foreach (sub{ 
 			#this sub wil receive the following:
 			my ($model,$path,$iter) =@_;
 			
 			#we want data at the model's column 0  
 			#where the iter is pointing
 			my $value = $model->get($iter,0);
 			print $value."\n";
 			
 			});	
 	});
 		
 $vbox->pack_end($btn_show_sel,FALSE,FALSE,0);
 
 $vbox->show_all();
 return $vbox;
 }

14.4.2.3. The Discussion

• The Gtk2::TreeSelection belonging to a Gtk2::TreeView can be used to define selection modes. To define its selection mode, we use its "set_mode" method. In our program we extract a list of possible values for the selection mode, by making use of Glib::Type's "list_values" method. We then use this and populate a Gtk2::ComboBox. This will enable us to change the selection mode.

  #------------------
  #get a list of Gtk2::SelectionModes and fill a combo box with it
  my $cmb_box = Gtk2::ComboBox->new_text;
  	 
  foreach my $s_type (Glib::Type->list_values ('Gtk2::SelectionMode')){
  	
  	$cmb_box->append_text($s_type->{'nick'});
  }
  	
  $cmb_box->set_active(0);
  #------------------

  To find out more about the values returned by "list_values", consult the chapter on Gtk2::MessageDialog, Chapter 8 -> "Types of messages" for more info.

• We set an initial selection mode and then we connect the Gtk2::ComboBox's "changed" signal to a sub that will change the selection mode of the Gtk2::TreeView accordingly (by making use of it's Gtk2::TreeSelection's "set_mode" method) to the selected text value of the Gtk2::ComboBox.

  #---------------------------------------------------
  #get the Gtk2::TreeSelection of $tree_view
  my $treeselection = $tree_view->get_selection;
  #set its initial mode
  $treeselection->set_mode($cmb_box->get_active_text);
  	
  #connect the combo box's changed signal so that it will
  #change the mode of the Gtk2::TreeSelection on each change.
  $cmb_box->signal_connect('changed' => sub {
  	
  	$treeselection->set_mode($cmb_box->get_active_text);
  });
  #-----------------------------------------------------

• To get a selection from a Gtk2::TreeView we have a few methods at our disposal.

  • If the select mode is such that only one item can be selected, we can use the "get_selected" method. This will return a Gtk2::TreeIter, pointing to the selected row in the model.

  • For one and more selectable items, we can use the "selected_foreach" method. This is used to loop the selected items, calling a subroutine for each. We use this one in our program, since we can have a select mode where one or more items is selectable.

    my $treeselection = $tree_view->get_selection;
    		
    $treeselection->selected_foreach (sub{ 
    	#this sub wil receive the following:
    	my ($model,$path,$iter) =@_;
    			
    	#we want data at the model's column 0  
    	#where the iter is pointing
    	my $value = $model->get($iter,0);
    	print $value."\n";
    			
    	});	

  • The "get_selected_rows" method will return a list of Gtk2::TreePaths pointing to each selected row. This can then be further used to get the selected values from the model. We get the Gtk2::TreeIter by using the model's "get_iter" method, and passing it the Gtk2::TreePath as argument.